# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/www/viewcvs.gentoo.org/raw_cvs/gentoo-x86/app-admin/apache-tools/apache-tools-2.2.4-r3.ebuild,v 1.2 2007/07/29 16:43:05 phreak Exp $

EAPI="prefix"

inherit flag-o-matic eutils

DESCRIPTION="Useful Apache tools - htdigest, htpasswd, ab, htdbm"
HOMEPAGE="http://httpd.apache.org/"
SRC_URI="mirror://apache/httpd/httpd-${PV}.tar.bz2"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~mips ~x86 ~x86-macos"
IUSE="ssl"
RESTRICT="test"

RDEPEND="=dev-libs/apr-1*
	=dev-libs/apr-util-1*
	dev-libs/libpcre
	ssl? ( dev-libs/openssl )
	!<www-/apache-2.2.4
	!<net-www/apache-2.2.4"

DEPEND="${RDEPEND}"

S="${WORKDIR}/httpd-${PV}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Apply these patches:
	# (1)	apache-tools-Makefile.patch:
	#		- fix up the `make install' for support/
	#		- remove envvars from `make install'
	# (2)	apache-tools-ab-ssl.patch:
	#		- Add support for SSL-capable version of ab
	epatch "${FILESDIR}"/${PN}-Makefile.patch
	use ssl && epatch "${FILESDIR}"/${PN}-ab-ssl.patch
}

src_compile() {
	local myconf=""
	cd "${S}"

	# Instead of filtering --as-needed (bug #128505), append --no-as-needed
	# Thanks to Harald van Dijk
	if [[ ${CHOST} != *-darwin* ]]; then
		append-ldflags -Wl,--no-as-needed
	fi

	use ssl && myconf="${myconf} --with-ssl=${EPREFIX}/usr"

	# econf overwrites the stuff from config.layout, so we have to put them into
	# our myconf line too

	econf \
		--sbindir=${EPREFIX}/usr/sbin \
		--with-perl=${EPREFIX}/usr/bin/perl \
		--with-expat=${EPREFIX}/usr \
		--with-z=${EPREFIX}/usr \
		--with-apr=${EPREFIX}/usr \
		--with-apr-util=${EPREFIX}/usr \
		--with-pcre=${EPREFIX}/usr \
		${myconf} || die "econf failed!"

	cd support
	emake || die "emake support/ failed!"
}

src_install () {
	cd "${S}"/support

	make DESTDIR="${D}" install || die "make install failed!"

	# install manpages
	doman "${S}"/docs/man/{dbmmanage,htdigest,htpasswd,htdbm}.1 \
		"${S}"/docs/man/{ab,htcacheclean,logresolve,rotatelogs}.8

	# Providing compatiblity symlinks for #177697 (which we'll stop to install
	# at some point).

	for i in $(ls "${ED}"/usr/sbin 2>/dev/null); do
		dosym /usr/sbin/${i} /usr/sbin/${i}2
	done

	# Provide a symlink for ab-ssl
	if use ssl ; then
		dosym /usr/sbin/ab /usr/sbin/ab-ssl
		dosym /usr/sbin/ab /usr/sbin/ab2-ssl
	fi

	dodoc "${S}"/CHANGES
}